# Custom Keyboard shortcuts

**URL:** https://community.mp3tag.de/t/custom-keyboard-shortcuts/18691
**Category:** General Discussion
**Created:** [February 10, 2017, 2:25pm UTC](https://community.mp3tag.de/t/custom-keyboard-shortcuts/18691 "2017-02-10T14:25:45Z")
**Posts on this page:** 1
**Showing post:** 6

<div class="post-metadata">

### Author: ![stevehero](https://community.mp3tag.de/user_avatar/community.mp3tag.de/stevehero/32/337_2.png) [@stevehero](https://community.mp3tag.de/u/stevehero)
#### Post date: [July 23, 2017, 9:29pm UTC](https://community.mp3tag.de/t/custom-keyboard-shortcuts/18691/6 "2017-07-23T21:29:15Z")

</div>

AutoHotkey can do what you want + MORE 🙂

- Install [this](https://autohotkey.com/download/ahk-install.exe)
- **RMB on your desktop\>New\>AutoHotkey Script**
- Rename the file to **AHK\_mp3tag.ahk** for example. Just make sure the extension is **.ahk**
- Double click the newly created file.

This **AHK\_mp3tag.ahk** file could be loaded very time windows starts.  
Just hit **win+R** key and type **shell:startup** and paste that file in there and you should be good to go. Or if you had trouble like me in the past with win 10 use **shell:Common Startup** instead.

See notes for usage.

```
;
; Mp3Tag - Re-mappings and custom keyboard short-cuts by stevehero
; Allowing custom keyboard short-cuts ONLY while the active windows is Mp3Tag.
;

; ALT+M, Global hot key to suspend all of these keyboard short-cuts.
!m::Suspend

;
; Short-cut: ALT+6
; Remap Alt+6 to automatically accept the next pop-up dialog
; The dialog is still available by clicking it on the toolbar.
; This short-cut merely avoids having to click OK.
;
#IfWinActive ahk_exe Mp3tag.exe
    !6::
    Sleep, 400
    send, !{6}
    send, {enter}
    Return
#IfWinActive

;
; Short-cut: CTRL+N
; Remap TRACK Auto-Renumber
;
#IfWinActive ahk_exe Mp3tag.exe
    ^n::
    Sleep, 500
    send, {LAlt}
    send, {o}
    send, {Down 1}
    send, {enter}
; This next line accepts the AR dialog
    send, {enter}
    Return
#IfWinActive

;
; Short-cut: CTRL+T
; Quick RMB Tool Context menu
; If you want this to fire up a tool in mp3Tag, then rename
; the tool to have an ampersands in the name to represent the last button pressed.
; e.g. '&Youtube Search' (see {y} below)
;
#IfWinActive ahk_exe Mp3tag.exe
    ^t::
    Sleep, 400
    SendInput {control down}{shift down}{f10 down}
    SendInput {control up}{shift up}{f10 up}
    send, {t}
; Line below is optional. Here you can fire up the tool using the letter represented by the & in the tool name.
; send, {y}
    Return
#IfWinActive

;
; Short-cut: CTRL+SHIFT+S
; Works only when explorer.exe is the active window.
; Taken from AHK forum from user jeeswg: https://autohotkey.com/boards/viewtopic.php?p=160589#p160589
; Many thanks for that
; Change the path to whatever path your Spek.exe lies.
;
#IfWinActive, ahk_exe explorer.exe
    ^+s::;explorer - open selected file in SPEK
    Clipboard := ""
    Send, ^c
    ClipWait
    vPath := Clipboard
    if !FileExist(vPath)
        return
    WinGet, hWnd, ID, Spek - ahk_class wxWindowNR
    if !hWnd
    {
            Run, "C:\Program Files (x86)\Spek\spek.exe" "%vPath%"
        return
    }
    WinActivate, % "ahk_id " hWnd
    WinWaitActive, % "ahk_id " hWnd
    PostMessage, 0x111, 5000,,, % "ahk_id " hWnd;WM_COMMAND
    WinWaitActive, Open File ahk_class #32770 ahk_exe spek.exe
    WinGet, hWnd2, ID, Open File ahk_class #32770 ahk_exe spek.exe
    ControlSetText, Edit1, % vPath, % "ahk_id " hWnd2
    ControlClick, Button1, % "ahk_id " hWnd2
    return
#IfWinActive

```

You've got 500millisecs (half second) in which to hit the commands and lift off or else the code won't fire.

**Reason for edit:** Added additional code and added a suspend script to ALT+M.

---

_[View the full topic](https://community.mp3tag.de/t/custom-keyboard-shortcuts/18691)._