Bilddateien kopieren

Hallo Community!

Ist es möglich mit Mp3Tag Bilder zu kopieren?

Meine Sammlung ist Folgendermassen organisiert:

  • Interpret1
    -- Album1
    -- Album2
  • Interpret2
    -- Album1
    -- Album2
  • Interpret3
    -- Album1
    (...)

In den Verzeichnissen AlbumX befinden sich die CD Cover als jpeg Dateien. Die Namensgebung variiert leicht: 00 - Front.jpg, 00 - Front.jpeg, 00 - Front.JPG, 00 - Front.JPEG, 000 - Front.jpg, 000 - Front.jpeg, 000 - Front.JPG, 000 - Front.JPEG

Nun möchte ich aus diesen Front JPGs jeweils eine Kopie im selben Verzeichnis mit Namen "folder.jpg" automatisiert erstellen. Manuell ist das bei knapp 6000 Verzeichnissen leider etwas aufwändig. Funktioniert das also mit Mp3Tag? Und wenn ja wie?

Kenne mich leider nicht so aus, bisher habe ich das Programm nur benutzt um für jeden Ordner eine Playlist zu erstellen. Bin also für jede Hilfe dankbar.

Ich weiß nicht ob das mit Mp3tag machbar ist, ganz bestimmt nicht mit vertretbarem Aufwand.

Ich würde diese Aufgabe zum Beispiel mit einem Kommandozeilenbefehl erledigen.

  1. Kommandozeilenprogramm cmd.exe öffnen.
    Zum Beispiel mit [WinKey+R] und Eingabe "cmd" und [OK].

  2. Den Stammordner der Interpreten Ordnerstruktur zum aktuellen Ordner machen.
    Zum Beispiel mit dem Befehl:

cd /d "Ordnerpfad"
  1. Befehl eingeben (eine Zeile):

    for /f "usebackq tokens=*" %p in (dir /b/s "00*.jp*g") do (copy "%p" "%~dppfolder.jpg")

  2. Fertig.

In jedem Ordner, in dem eine Datei gefunden wird, die dem Suchmuster entspricht, wird eine Kopie dieser Datei mit dem Namen "folder.jpg" angelegt.

Man kann vorher einen Testlauf machen mit dem Befehl (eine Zeile):

for /f "usebackq tokens=*" %p in (`dir /b/s "00*.jp*g"`) do (echo.copy "%p" "%~dppfolder.jpg")

Wenn "doppelte" Dateien gefunden werden, dann fragt der copy Befehl was zu tun ist.
Diese Frage kann man unterdrücken durch die Option "/y".

for /f "usebackq tokens=*" %p in (`dir /b/s "00*.jp*g"`) do (copy /y "%p" "%~dppfolder.jpg")

DD.20101115.2052.CET

Vielen Dank. Habe gerade einen kleinen Testlauf mit 10 Verzeichnissen gemacht und es scheint zu funktionieren! :slight_smile:

Hatte schon ohne Ende gegoogelt, aber nie etwas so einfaches gefunden. Am besten wäre zusätzlich noch ein automatisches Resize der kopierten Bilddateien auf 300 mal 300 Pixel, aber das wird wohl ein Traum bleiben. Ist mir bewusst, dass da kein One-Klick-Tool für existiert. Also erst die vorgeschlagene Kommandozeile und dann eine Stapelverarbeitung auf die folder.jpg anwenden ... ist noch erträglich.

Eine Verständnisfrage noch, der Ausdruck "00*.jp*g" erwischt wirklich alle vier Dateiendungen (jpg, jpeg, JPG, JPEG)?

  • EDIT -

Mist, zu früh gefreut!

Ich hätte erwähnen sollen, dass in den Verzeichnissen auch noch 00 - Back.jpg und 00 - Inlay.jpg usw. vorhanden sind.

Mit "00F.jp*g" scheint das aber behoben zu sein, sehe ich das richtig?

Eigentliche hatte ich diese Rückfrage schon erwartet. Schnellbie, was du siehst, das kann ich nicht sehen. Ob etwas vor Ort bei dir funktioniert oder nicht, dafür bist du der Entscheider.

Für beste Zuverlässigkeit sollte man jeden Fall eines unterscheidbaren Dateinamens einzeln bearbeiten.
00 - Front.jpg
00 - Front.JPG

00 - Front.jpeg
00 - Front.JPEG

000 - Front.jpg
000 - Front.JPG

000 - Front.jpeg
000 - Front.JPEG

Wenn andere Fälle nicht zu erwarten sind, dann lassen sich diese Fälle zusammenfassen.
"00* - Front.jp*g"

Diese Dateimaske kann man weiter verallgemeinern zu "00F.jp*g", aber dann könnten auch Dateinamen gefunden wie zum Beispiel "00123 Fritz Müller.jpläg".

Zur Bildbearbeitung im Stapelverfahren empfehle ich Irfanview.
Zum Beispiel mit diesem Kommanozeilenbefehl:

for /f "usebackq tokens=*" %a in (`dir /b/s "00* - Front.jp*g"`) do ("C:\Programme\IrfanView\i_view32.exe" ^"%a^" ^/resize=^(300,300^) ^/aspectratio ^/resample ^/jpgq=95 ^/convert=^"%~dpafolder.jpg^")

Beispiel für eine "one-click" Kommandozeilendatei:

REM Wurzelordner definieren.
CD /D "T:\TEST\T1\"
REM Bild bearbeiten.
FOR /F "usebackq tokens=*" %%a IN (`DIR /B /S "00* - Front.jp*g"`) DO ("C:\Programme\IrfanView\i_view32.exe" ^"%%a^" ^/resize=^(300,300^) ^/aspectratio ^/resample ^/jpgq=95 ^/convert=^"%%~dpafolder.jpg^")
PAUSE

DD.20101116.0554.CET

Danke für die sehr ausführliche Antwort!

Werde das am Wochenende alles mal ausprobieren...

Habe nun doch schon etwas Zeit gefunden und möchte Rückmeldung geben.

Die vorgeschlagene Kommandozeilendatei für IrfanView hat den Job bestens erledigt. Nach ein paar Minuten schon war meine Ordnerstruktur fehlerfrei(!) bearbeitet.

Vielen Dank nochmal @DetlevD !